SUBROUTINE PDISK_SUB(OUTPUT_FILE, ERROR_FLAG)
* Subroutine shell for PDISK routine
* 05/31/96 - BTS - Original release of program

DECLARE SUBROUTINE MSG, CATALYST, FSMSG

EQUATE TRUE$  TO 1
EQUATE FALSE$ TO 0

ERROR_FLAG = FALSE$

OSOPEN OUTPUT_FILE TO FILEVAR THEN
    OSCLOSE OUTPUT_FILE
    MESSAGE_TEXT = "|The ":QUOTE(OUTPUT_FILE):" file already exists."
    MESSAGE_TEXT:= "|Do you wish to overwrite it?|"
    * display a message and solicit a response
    RESP =  '' ; * initialize variable to hold response
    MSG(MESSAGE_TEXT,"BOC",RESP,'')
    IF NOT(RESP) THEN
         ERROR_FLAG = TRUE$
         RETURN
    END
END

OSWRITE OUTPUT_FILE TO OUTPUT_FILE
ERROR_FLAG = STATUS()
IF ERROR_FLAG = FALSE$ THEN
    OSDELETE OUTPUT_FILE
    ERROR_FLAG = STATUS()
    IF ERROR_FLAG = FALSE$ THEN
         CATALYST('E','PDISK ':OUTPUT_FILE:" (S)")
    END ELSE
         GOSUB ERROR_MSG:
    END
END ELSE
    GOSUB ERROR_MSG:
END

RETURN

ERROR_MSG:

BEGIN CASE
     CASE ERROR_FLAG = 2 OR ERROR_FLAG = 6
         MESSAGE_TEXT = "|Access was denied by the operating system.|"
     CASE ERROR_FLAG = 3
         MESSAGE_TEXT = "|The Disk or Directory is full.|"
     CASE 1
         MESSAGE_TEXT = "|The file name was not valid to the operating system.|"
         MESSAGE_TEXT:= QUOTE(OUTPUT_FILE):"|"
END CASE

MSG(MESSAGE_TEXT)
ERROR_FLAG = TRUE$

RETURN